_pkgname="vdhcoapp"
pkgname="$_pkgname-test-bin"
pkgver=2.0.19
pkgrel=1
pkgdesc="Companion application for Video DownloadHelper browser add-on"
url="https://github.com/aclap-dev/vdhcoapp"
license=('GPL-2.0-or-later')
arch=('x86_64')

options=('emptydirs' '!strip' '!debug')
install="$_pkgname.install"

provides=("$_pkgname=$pkgver")
conflicts=("$_pkgname")

source=("vdhcoapp-$pkgver-linux-$arch.deb"::"$url/releases/download/v${pkgver}/vdhcoapp-linux-$arch.deb")
sha256sums=('496d341eef326f3fb6f0ddf825b309d6e18a4ddb7f1bec7fe74d9282ae94dfc4')

package() {
  depends+=('ffmpeg')

  bsdtar -xf data.tar.xz -C "$pkgdir" opt/vdhcoapp/filepicker opt/vdhcoapp/vdhcoapp

  ln -sf /usr/bin/ffmpeg "$pkgdir/opt/vdhcoapp/ffmpeg"
  ln -sf /usr/bin/ffprobe "$pkgdir/opt/vdhcoapp/ffprobe"

  install -dm755 "$pkgdir/usr/bin"
  ln -sf "/opt/vdhcoapp/vdhcoapp" "$pkgdir/usr/bin/vdhcoapp"

  install -dm755 "$pkgdir/usr/lib/mozilla/native-messaging-hosts/"
  install -dm755 "$pkgdir/etc/opt/chrome/native-messaging-hosts/"
  install -dm755 "$pkgdir/etc/chromium/native-messaging-hosts/"
  install -dm755 "$pkgdir/etc/opt/edge/native-messaging-hosts/"

  chmod -R u+rwX,go+rX,go-w "$pkgdir/"
}

cat > vdhcoapp.install << 'END'
post_install() {
  echo "vdhcoapp: system install"
  vdhcoapp install --system
}

post_upgrade() {
  echo "vdhcoapp: system install"
  vdhcoapp install --system
}

pre_remove() {
  echo "vdhcoapp: system uninstall"
  vdhcoapp uninstall --system
}
END